Sadržaj
- Pretražujte u Excelu po više kriterija
- Izdvajamo 2., 3. itd. vrijednosti pomoću VLOOKUP-a
- Dohvatite sva ponavljanja željene vrijednosti
- XNUMXD pretraživanje po poznatom retku i stupcu
- Korištenje više VLOOKUP-ova u jednoj formuli
- Dinamička zamjena podataka iz različitih tablica pomoću VLOOKUP-a i INDIRECT-a
U drugom dijelu našeg vodiča o funkciji VPR (VLOOKUP) u Excelu, analizirat ćemo nekoliko primjera koji će vam pomoći da usmjerite svu snagu VPR za rješavanje najambicioznijih Excel zadataka. Primjeri pretpostavljaju da već imate osnovno znanje o tome kako ova značajka radi. Ako niste, možda bi vas zanimalo započeti s prvim dijelom ovog vodiča, koji objašnjava sintaksu i osnovnu upotrebu. VPR. Pa, počnimo.
Pretražujte u Excelu po više kriterija
funkcija VPR u Excelu je stvarno moćan alat za izvođenje pretraživanja za određenu vrijednost u bazi podataka. Međutim, postoji značajno ograničenje – njegova sintaksa omogućuje pretraživanje samo jedne vrijednosti. Što ako želite pretraživati prema više uvjeta? Rješenje ćete pronaći u nastavku.
Primjer 1: Pretraživanje po 2 različita kriterija
Pretpostavimo da imamo popis narudžbi i želimo pronaći Količina robe (kol.), na temelju dva kriterija – Ime klijenta (Kupac) i Proglašenje proizvoda (Proizvod). Stvar je komplicirana činjenicom da je svaki od kupaca naručio više vrsta robe, što je vidljivo iz donje tablice:
redovita funkcija VPR neće raditi u ovom scenariju jer će vratiti prvu vrijednost koju nađe koja odgovara danoj vrijednosti pretraživanja. Na primjer, ako želite znati količinu artikla slatkišipo narudžbi kupca Jeremy Hill, napišite sljedeću formulu:
=VLOOKUP(B1,$A$5:$C$14,3,FALSE)
=ВПР(B1;$A$5:$C$14;3;ЛОЖЬ)
– ova formula će vratiti rezultat 15koji odgovara proizvodu jabuke, jer je to prva vrijednost koja odgovara.
Postoji jednostavno zaobilazno rješenje – izradite dodatni stupac u kojem ćete kombinirati sve željene kriterije. U našem primjeru to su stupci Ime klijenta (Kupac) i Proglašenje proizvoda (Proizvod). Ne zaboravite da spojeni stupac uvijek mora biti krajnji lijevi stupac u rasponu pretraživanja, budući da je to lijevi stupac u kojem funkcija VPR podiže pogled kada traži vrijednost.
Dakle, dodajete pomoćni stupac u tablicu i kopirate sljedeću formulu preko svih njenih ćelija: =B2&C2. Ako želite da niz bude čitljiviji, možete razdvojiti kombinirane vrijednosti razmakom: =B2&» «&C2. Nakon toga možete koristiti sljedeću formulu:
=VLOOKUP("Jeremy Hill Sweets",$A$7:$D$18,4,FALSE)
=ВПР("Jeremy Hill Sweets";$A$7:$D$18;4;ЛОЖЬ)
or
=VLOOKUP(B1,$A$7:$D$18,4,FALSE)
=ВПР(B1;$A$7:$D$18;4;ЛОЖЬ)
Gdje je ćelija B1 sadrži ulančanu vrijednost argumenta tražena_vrijednost (vrijednost_traženja) i 4 – Argument col_index_num (broj_stupca), tj. broj stupca koji sadrži podatke koje treba dohvatiti.
Primjer 2: VLOOKUP prema dva kriterija s pregledom tablice na drugom listu
Ako trebate ažurirati glavnu tablicu (Main table) dodavanjem podataka iz druge tablice (Lookup table), koja se nalazi na drugom listu ili u drugoj Excel radnoj knjizi, tada željenu vrijednost možete prikupiti izravno u formuli koju umetnete u glavnu tablicu.
Kao u prethodnom primjeru, trebat će vam pomoćni stupac u tablici pretraživanja s kombiniranim vrijednostima. Ovaj stupac mora biti krajnji lijevi stupac u rasponu pretraživanja.
Dakle, formula sa VPR može biti ovako:
=VLOOKUP(B2&" "&C2,Orders!$A&$2:$D$2,4,FALSE)
=ВПР(B2&" "&C2;Orders!$A&$2:$D$2;4;ЛОЖЬ)
Ovdje stupci B i C sadrže imena kupaca odnosno proizvoda i vezu Narudžbe!$A&$2:$D$2 definira tablicu za traženje na drugom listu.
Kako biste formulu učinili čitljivijom, rasponu prikaza možete dati ime i tada će formula izgledati puno jednostavnije:
=VLOOKUP(B2&" "&C2,Orders,4,FALSE)
=ВПР(B2&" "&C2;Orders;4;ЛОЖЬ)
Da bi formula radila, vrijednosti u krajnjem lijevom stupcu tablice koju gledate moraju se kombinirati na potpuno isti način kao u kriterijima pretraživanja. Na gornjoj slici smo kombinirali vrijednosti u2bu2band i stavili razmak između njih, na isti način na koji trebate učiniti u prvom argumentu funkcije (BXNUMX& “” & CXNUMX).
Zapamtiti! funkcija VPR ograničen na 255 znakova, ne može tražiti vrijednost koja je duža od 255 znakova. Imajte to na umu i pazite da duljina željene vrijednosti ne premaši ovu granicu.
Slažem se da dodavanje pomoćnog stupca nije najelegantnije i ne uvijek prihvatljivo rješenje. Možete učiniti isto bez pomoćnog stupca, ali to bi zahtijevalo mnogo složeniju formulu s kombinacijom funkcija INDEKS (KAZALO) i MATCH (EKSPONIJENIJE).
Izdvajamo 2., 3. itd. vrijednosti pomoću VLOOKUP-a
To već znaš VPR može vratiti samo jednu odgovarajuću vrijednost, točnije prvu pronađenu. Ali što ako se ova vrijednost ponavlja nekoliko puta u prikazanom nizu, a vi želite izdvojiti drugu ili treću od njih? Što ako sve vrijednosti? Problem se čini kompliciranim, ali rješenje postoji!
Pretpostavimo da jedan stupac tablice sadrži imena kupaca (Customer Name), a drugi stupac sadrži proizvode (Product) koje su kupili. Pokušajmo pronaći 2., 3. i 4. stavku koju je kupio određeni kupac.
Najlakši način je dodati pomoćni stupac prije stupca Ime kupca i ispunite ga imenima kupaca s brojem ponavljanja svakog imena, na primjer, John Doe1, John Doe2 itd. Napravit ćemo trik s numeriranjem pomoću funkcije COUNTIF (COUNTIF), s obzirom da su imena kupaca u stupcu B:
=B2&COUNTIF($B$2:B2,B2)
=B2&СЧЁТЕСЛИ($B$2:B2;B2)
Nakon toga možete koristiti normalnu funkciju VPRpronaći traženi redoslijed. Na primjer:
- naći 2-og artikal koji naruči kupac Dan Brown:
=VLOOKUP("Dan Brown2",$A$2:$C$16,3,FALSE)=ВПР("Dan Brown2";$A$2:$C$16;3;ЛОЖЬ) - naći 3-og artikal koji naruči kupac Dan Brown:
=VLOOKUP("Dan Brown3",$A$2:$C$16,3,FALSE)=ВПР("Dan Brown3";$A$2:$C$16;3;ЛОЖЬ)
Zapravo, možete unijeti referencu ćelije kao vrijednost pretraživanja umjesto teksta, kao što je prikazano na sljedećoj slici:
Ako samo tražite 2-e ponavljanje, možete to učiniti bez pomoćnog stupca stvaranjem složenije formule:
=IFERROR(VLOOKUP($F$2,INDIRECT("$B$"&(MATCH($F$2,Table4[Customer Name],0)+2)&":$C16"),2,FALSE),"")
=ЕСЛИОШИБКА(ВПР($F$2;ДВССЫЛ("$B$"&(ПОИСКПОЗ($F$2;Table4[Customer Name];0)+2)&":$C16");2;ИСТИНА);"")
U ovoj formuli:
- $F$2 – ćelija koja sadrži ime kupca (nepromijenjeno, napominjemo – poveznica je apsolutna);
- $ B $ - stupac Ime kupca;
- Table4 – Vaš stol (ovo mjesto može biti i obični asortiman);
- C16 USD – krajnja ćelija vaše tablice ili raspona.
Ova formula pronalazi samo drugu odgovarajuću vrijednost. Ako trebate izdvojiti preostala ponavljanja, upotrijebite prethodno rješenje.
Ako trebate popis svih podudaranja – funkcija VPR ovo nije pomoćnik jer vraća samo jednu po jednu vrijednost – točku. Ali Excel ima funkciju INDEKS (INDEX), koji se lako može nositi s ovim zadatkom. Kako će takva formula izgledati, saznat ćete u sljedećem primjeru.
Dohvatite sva ponavljanja željene vrijednosti
Kao što je gore navedeno VPR ne može izdvojiti sve duplicirane vrijednosti iz skeniranog raspona. Da biste to učinili, potrebna vam je malo složenija formula, sastavljena od nekoliko Excel funkcija, kao npr INDEKS (INDEKS), MALI (MALA) i RED (CRTA)
Na primjer, formula u nastavku pronalazi sva ponavljanja vrijednosti iz ćelije F2 u rasponu B2:B16 i vraća rezultat iz istih redaka u stupcu C.
{=IFERROR(INDEX($C$2:$C$16,SMALL(IF($F$2=B2:B16,ROW(C2:C16)-1,""),ROW()-3)),"")}
{=ЕСЛИОШИБКА(ИНДЕКС($C$2:$C$16;НАИМЕНЬШИЙ(ЕСЛИ($F$2=B2:B16;СТРОКА(C2:C16)-1;"");СТРОКА()-3));"")}
Unesite ovu formulu polja u više susjednih ćelija, kao što su ćelije F4: F8kao što je prikazano na donjoj slici. Broj ćelija mora biti jednak ili veći od najvećeg mogućeg broja ponavljanja tražene vrijednosti. Ne zaboravi kliknuti Ctrl + Shift + Enterkako biste pravilno unijeli formulu polja.
Ako ste zainteresirani za razumijevanje kako to funkcionira, zaronimo malo u detalje formule:
Dio 1:
IF($F$2=B2:B16,ROW(C2:C16)-1,"")
ЕСЛИ($F$2=B2:B16;СТРОКА(C2:C16)-1;"")
$F$2=B2:B16 – usporedite vrijednost u ćeliji F2 sa svakom od vrijednosti u rasponu B2:B16. Ako se pronađe podudaranje, izraz STRING(C2:C16)-1 vraća broj odgovarajućeg retka (vrijednost -1 omogućuje vam da ne uključite redak zaglavlja). Ako nema podudaranja, funkcija IF (IF) vraća prazan niz.
Rezultat funkcije IF (AKO) postojat će takav horizontalni niz: {1,"",3,"",5,"","","","","","",12,"","",""}
Dio 2:
ROW()-3
СТРОКА()-3
Evo funkcije RED (LINE) služi kao dodatni brojač. Budući da se formula kopira u ćelije F4:F9, oduzimamo broj 3 iz rezultata funkcije za dobivanje vrijednosti 1 u ćeliji F4 (redak 4, oduzmi 3) da dobiješ 2 u ćeliji F5 (redak 5, oduzmi 3) i tako dalje.
Dio 3:
SMALL(IF($F$2=B2:B16,ROW(C2:C16)-1,""),ROW()-3))
НАИМЕНЬШИЙ(ЕСЛИ($F$2=B2:B16;СТРОКА(C2:C16)-1;"");СТРОКА()-3))
funkcija MALI (MALA) se vraća n-oh najmanja vrijednost u nizu podataka. U našem slučaju, koju poziciju (od najmanje) vratiti određuje funkcija RED (LINE) (vidi 2. dio). Dakle, za ćeliju F4 funkcija MALO({polje},1) vraća 1-og (najmanji) element niza, tj 1. Za ćeliju F5 vraća 2-og najmanji element u nizu, tj 3, Itd
Dio 4:
INDEX($C$2:$C$16,SMALL(IF($F$2=B2:B16,ROW(C2:C16)-1,""),ROW()-3))
ИНДЕКС($C$2:$C$16;НАИМЕНЬШИЙ(ЕСЛИ($F$2=B2:B16;СТРОКА(C2:C16)-1;"");СТРОКА()-3))
funkcija INDEKS (INDEX) jednostavno vraća vrijednost određene ćelije u nizu C2:C16. Za ćeliju F4 funkcija INDEKS($C$2:$C$16) će se vratiti jabukeZa F5 funkcija INDEKS($C$2:$C$16) će se vratiti slatkiši i tako dalje.
Dio 5:
IFERROR()
ЕСЛИОШИБКА()
Na kraju smo formulu stavili unutar funkcije AKO POGREŠKA (IFERROR), jer je malo vjerojatno da ćete biti zadovoljni porukom o pogrešci #AT (#N/A) ako je broj ćelija u koje se kopira formula manji od broja dupliciranih vrijednosti u rasponu koji se gleda.
XNUMXD pretraživanje po poznatom retku i stupcu
Izvođenje XNUMXD pretraživanja u Excelu uključuje traženje vrijednosti prema poznatom broju retka i stupca. Drugim riječima, izvlačite vrijednost ćelije na sjecištu određenog retka i stupca.
Dakle, okrenimo se našoj tablici i napišimo formulu s funkcijom VPR, koji će pronaći informacije o cijeni limuna prodanih u ožujku.
Postoji nekoliko načina za obavljanje XNUMXD pretrage. Provjerite mogućnosti i odaberite onu koja vam najviše odgovara.
Funkcije VLOOKUP i MATCH
Možete koristiti hrpu funkcija VPR (VLOOKUP) i EKSPONIRANIJI (MATCH) za pronalaženje vrijednosti na sjecištu polja Proglašenje proizvoda (niz) i Mjesec (stupac) dotičnog niza:
=VLOOKUP("Lemons",$A$2:$I$9,MATCH("Mar",$A$1:$I$1,0),FALSE)
=ВПР("Lemons";$A$2:$I$9;ПОИСКПОЗ("Mar";$A$1:$I$1;0);ЛОЖЬ)
Gornja formula je regularna funkcija VPR, koji traži točno podudaranje vrijednosti "Limuni" u ćelijama od A2 do A9. Ali budući da ne znate u kojem se stupcu nalaze rasprodaje u ožujku, nećete moći postaviti broj stupca za treći argument funkcije. VPR. Umjesto toga koristi se funkcija EKSPONIRANIJIza definiranje ovog stupca.
MATCH("Mar",$A$1:$I$1,0)
ПОИСКПОЗ("Mar";$A$1:$I$1;0)
Prevedeno na ljudski jezik, ova formula znači:
- Tražimo likove “Mar” – argument tražena_vrijednost (vrijednost_traženja);
- Gledanje u ćelije od A1 do I1 – argument traženi_niz (niz_traženja);
- Vraća točno podudaranje – argument vrsta_podudaranja (vrsta_podudaranja).
Korištenje 0 u trećem argumentu kažete funkcije EKSPONIRANIJI potražite prvu vrijednost koja točno odgovara vrijednosti koju tražite. Ovo je ekvivalentno vrijednosti FALSE (FALSE) za četvrti argument VPR.
Ovako možete stvoriti formulu dvosmjernog pretraživanja u Excelu, također poznatu kao dvodimenzionalno pretraživanje ili dvosmjerno pretraživanje.
Funkcija SUMPRODUCT
funkcija SUMPRODUCT (SUMPRODUCT) vraća zbroj umnožaka odabranih nizova:
=SUMPRODUCT(($A$2:$A$9="Lemons")*($A$1:$I$1="Mar"),$A$2:$I$9)
=СУММПРОИЗВ(($A$2:$A$9="Lemons")*($A$1:$I$1="Mar");$A$2:$I$9)
Funkcije INDEX i MATCH
U sljedećem članku ću detaljno objasniti ove funkcije, tako da za sada možete samo kopirati ovu formulu:
=INDEX($A$2:$I$9,MATCH("Lemons",$A$2:$A$9,0),MATCH("Mar",$A$1:$I$1,0))
=ИНДЕКС($A$2:$I$9;ПОИСКПОЗ("Lemons";$A$2:$A$9;0);ПОИСКПОЗ("Mar";$A$1:$I$1;0))
Imenovani rasponi i operator presjeka
Ako ne volite sve te složene Excel formule, možda bi vam se svidio ovaj vizualni i nezaboravni način:
- Odaberite tablicu, otvorite karticu Formule (Formule) i kliknite Stvori iz odabira (Stvori iz odabira).
- Označite okvire Gornji red (na retku iznad) i Lijevi stupac (u stupcu lijevo). Microsoft Excel će dodijeliti imena rasponima iz vrijednosti u gornjem retku i lijevom stupcu vaše proračunske tablice. Sada možete izravno pretraživati koristeći ta imena bez stvaranja formula.
- Upišite u bilo koju praznu ćeliju =ime_reda ime_stupca, na primjer ovako:
=Limuni Mar
… ili obrnuto:
=Mar Lemons
Upamtite da nazivi redaka i stupaca moraju biti odvojeni razmakom, što u ovom slučaju funkcionira kao operator presjeka.
Kada unesete ime, Microsoft Excel će prikazati opis alata s popisom podudarnih imena, baš kao kada unesete formulu.
- tisak ući i provjerite rezultat
Općenito, koju god od gore navedenih metoda odabrali, rezultat dvodimenzionalnog pretraživanja bit će isti:
Korištenje više VLOOKUP-ova u jednoj formuli
Događa se da glavna tablica i tablica pretraživanja nemaju niti jedan zajednički stupac, što vas sprječava u korištenju uobičajene funkcije VPR. Međutim, postoji još jedna tablica koja ne sadrži informacije koje nas zanimaju, ali ima zajednički stupac s glavnom tablicom i tablicom za pretraživanje.
Pogledajmo sljedeći primjer. Imamo glavnu tablicu sa stupcem SKU (novo), gdje želite dodati stupac s pripadajućim cijenama iz druge tablice. Osim toga, imamo 2 tablice pretraživanja. Prva (Tražilačka tablica 1) sadrži ažurirane brojeve SKU (novo) i nazive proizvoda, a drugi (Lookup table 2) – nazive proizvoda i stare brojeve SKU (stari).
Da biste dodali cijene iz druge tablice pretraživanja u glavnu tablicu, morate izvršiti radnju poznatu kao dvostruko VPR ili ugniježđeni VPR.
- Napiši funkciju VPR, koji pronalazi naziv proizvoda u tablici Pregledna tablica 1koristeći Šifra proizvoda, kao željenu vrijednost:
=VLOOKUP(A2,New_SKU,2,FALSE)=ВПР(A2;New_SKU;2;ЛОЖЬ)Ovdje Novi_SKU – imenovani raspon $A:$B u stolu Pregledna tablica 1, 2 – ovo je stupac B koji sadrži nazive robe (vidi sliku iznad)
- Napišite formulu za umetanje cijena iz tablice Pregledna tablica 2 na temelju dobro poznatih naziva proizvoda. Da biste to učinili, zalijepite formulu koju ste ranije stvorili kao vrijednost pretraživanja za novu funkciju VPR:
=VLOOKUP(VLOOKUP(A2,New_SKU,2,FALSE),Price,3,FALSE)=ВПР(ВПР(A2;New_SKU;2;ЛОЖЬ);Price;3;ЛОЖЬ)Ovdje Cijena – imenovani raspon $A:$C u stolu Pregledna tablica 2, 3 je stupac C koji sadrži cijene.
Slika ispod prikazuje rezultat koji je vratila formula koju smo izradili:
Dinamička zamjena podataka iz različitih tablica pomoću VLOOKUP-a i INDIRECT-a
Prvo, razjasnimo što mislimo pod izrazom "Dinamička zamjena podataka iz različitih tablica" kako bismo bili sigurni da se ispravno razumijemo.
Postoje situacije kada postoji više listova s podacima istog formata, te je potrebno izdvojiti potrebne podatke iz određenog lista, ovisno o vrijednosti koja se upisuje u pojedinu ćeliju. Mislim da je to lakše objasniti na primjeru.
Zamislite da imate izvješća o prodaji za nekoliko regija s istim proizvodima i u istom formatu. Želite pronaći podatke o prodaji za određenu regiju:
Ako imate samo dva takva izvješća, onda možete koristiti sramotno jednostavnu formulu s funkcijama VPR и IF (IF) za odabir željenog izvješća za pretraživanje:
=VLOOKUP($D$2,IF($D3="FL",FL_Sales,CA_Sales),2,FALSE)
=ВПР($D$2;ЕСЛИ($D3="FL";FL_Sales;CA_Sales);2;ЛОЖЬ)
Gdje:
- $D$2 je ćelija koja sadrži naziv proizvoda. Imajte na umu da ovdje koristimo apsolutne reference kako bismo izbjegli promjenu vrijednosti pretraživanja prilikom kopiranja formule u druge ćelije.
- $D3 je ćelija s nazivom regije. Koristimo apsolutnu referencu stupca i relativnu referencu retka jer planiramo kopirati formulu u druge ćelije u istom stupcu.
- FL_Sales и CA_Prodaja – nazive tablica (ili imenovanih raspona) koje sadrže odgovarajuća izvješća o prodaji. Možete, naravno, koristiti uobičajene nazive listova i reference raspona ćelija, na primjer 'FL list'!$A$3:$B$10, ali imenovani rasponi mnogo su praktičniji.
Međutim, kada postoji mnogo takvih tablica, funkcija IF nije najbolje rješenje. Umjesto toga, možete koristiti funkciju INDIREKTNO (INDIRECT) za vraćanje željenog raspona pretraživanja.
Kao što vjerojatno znate, funkcija INDIREKTNO koristi se za vraćanje veze koju daje tekstualni niz, što je upravo ono što nam sada treba. Dakle, hrabro zamijenite u gornjoj formuli izraz funkcijom IF povezati s funkcijom INDIREKTNO. Evo kombinacije VPR и INDIREKTNO radi odlično sa:
=VLOOKUP($D$2,INDIRECT($D3&"_Sales"),2,FALSE)
=ВПР($D$2;ДВССЫЛ($D3&"_Sales");2;ЛОЖЬ)
Gdje:
- $D$2 – ovo je ćelija s nazivom proizvoda, nepromijenjena je zbog apsolutne veze.
- $D3 je ćelija koja sadrži prvi dio naziva regije. U našem primjeru, ovo FL.
- _Prodajni – zajednički dio naziva svih imenovanih raspona ili tablica. Kada se kombinira s vrijednošću u ćeliji D3, tvori potpuno kvalificirano ime potrebnog raspona. Ispod su neki detalji za one koji su novi u funkciji INDIREKTNO.
Kako rade INDIRECT i VLOOKUP
Prvo, dopustite da vas podsjetim na sintaksu funkcije INDIREKTNO (INDIREKTNO):
INDIRECT(ref_text,[a1])
ДВССЫЛ(ссылка_на_текст;[a1])
Prvi argument može biti referenca ćelije (stil A1 ili R1C1), naziv raspona ili tekstualni niz. Drugi argument određuje koji je stil veze sadržan u prvom argumentu:
- A1ako je argument PRAVI KOD (TRUE) ili nije navedeno;
- R1C1, Ako FKAO E (NETOČNO).
U našem slučaju, veza ima stil A1, tako da možete izostaviti drugi argument i usredotočiti se na prvi.
Dakle, vratimo se našim izvještajima o prodaji. Ako se sjećate, onda je svaki izvještaj zasebna tablica koja se nalazi na posebnom listu. Da bi formula radila ispravno, morate imenovati svoje tablice (ili raspone), a sva imena moraju imati zajednički dio. Na primjer, ovako: CA_Prodaja, FL_Prodaja, TX_Prodaja i tako dalje. Kao što vidite, "_Sales" je prisutan u svim nazivima.
funkcija INDIREKTNO povezuje vrijednost u stupcu D i tekstualni niz “_Sales”, čime govori VPR u kojoj tablici tražiti. Ako ćelija D3 sadrži vrijednost "FL", formula će pretraživati tablicu FL_Prodaja, ako je “CA” – u tablici CA_Prodaja i tako dalje.
Rezultat funkcija VPR и INDIREKTNO bit će sljedeće:
Ako se podaci nalaze u različitim Excel knjigama, tada trebate dodati naziv knjige ispred imenovanog raspona, na primjer:
=VLOOKUP($D$2,INDIRECT($D3&"Workbook1!_Sales"),2,FALSE)
=ВПР($D$2;ДВССЫЛ($D3&"Workbook1!_Sales");2;ЛОЖЬ)
Ako funkcija INDIREKTNO odnosi se na drugu radnu knjigu, ta radna knjiga mora biti otvorena. Ako je zatvorena, funkcija će prijaviti pogrešku. #REF! (#SSYL!).